Automating callback numbers for Click to dial

From version 2.4 of ContactWorld for Salesforce (CW4SF), if enabled for your account, you can configure CW4SF to dynamically select a callback number. The dynamically selected callback number takes precedence for individual calls over both the callback number defined by your agent in ContactPad and your account's default callback number. For information on callback numbers, see Callback numbers.

You can use this feature in various ways depending on how your Salesforce org is set up. To override callback numbers, you must create a custom Apex class that implements the NVMContactWorld.ISelectPresentedClid interface and defines the GetPresentedClid method. The GetPresentedClid method describes how CW4SF can generate or locate the callback number. CW4SF can then present this number as the callback number.

To create the custom class, you must be familiar with creating Apex classes in Salesforce. For information on creating Apex classes, see Salesforce help.

NVMContactWorld.ISelectPresentedClid interface definition

global interface ISelectPresentedClid{
	String GetPresentedClid(String clickToDialResult);
}

The clickToDialResult contains the phone number that the agent clicked to dial, and the object ID and type of the Salesforce object from which the agent clicked. clickToDialResult is in JSON string format, for example, {"number":"4155551212","objectId":"001x0000003DIGj","object":"Account"}. You do not need to provide clickToDialResult because Salesforce passes the value to the method for you when an agent initiates a Click to dial event.

GetPresentedClid returns the callback number as a String object.

CW4SF validates the value returned by the GetPresentedClid method according to the following rules:

• if a null value is returned, the Click to dial call continues and CW4SF uses the agent's default callback number, if set, or the account's default callback number
• if a non-null value is returned but the value is not configured as a callback number for the account, the agent receives an error message
• if a non-null value is returned and the value is configured as a callback number for the account, but that callback number is restricted from the agent, the agent receives an error message
• if a non-null value is returned and if the value is configured as a callback number for the account and that callback number is not restricted from the agent, the Click to dial call continues, and the value is used as the callback number for the call

global class SelectPresentedClidForContactByAccount implements NVMContactWorld.ISelectPresentedClid{
    
    // The clickToDialResult parameter contains the response string from the Salesforce ClickToDial event.
    // Salesforce passes the clickToDialResult parameter to us:
    // for example '{number: "07890123456", objectId: "0032000001FTGSo", object: "Contact"}'
    // Find more information at: https://www.salesforce.com/us/developer/docs/api_cti/Content/sforce_api_cti_onclicktodial.htm
 
    global String GetPresentedClid(String clickToDialResult){
         
        Map<String,Object> clickToDialResultMap = (Map<String,Object>)JSON.deserializeUntyped(clickToDialResult);
        String contactId = (String)clickToDialResultMap.get('objectId');
         
        Contact c = [SELECT Id, AccountId FROM Contact WHERE Id = :contactId];
        Account a = [SELECT Id, ClickToDialPresentedClid__c FROM Account WHERE Id = :c.AccountId];
         
        String presentedClid = a.ClickToDialPresentedClid__c;
         
        return presentedClid;       
    }
}

global class SelectPresentedClidByPolicy implements NVMContactWorld.ISelectPresentedClid{
     
    // The clickToDialResult parameter contains the response string from the Salesforce ClickToDial event.
    // Salesforce passes the clickToDialResult parameter to us:
    // for example '{number: "07890123456", objectId: "0032000001FTGSo", object: "Contact"}'
    // Find more information at: https://www.salesforce.com/us/developer/docs/api_cti/Content/sforce_api_cti_onclicktodial.htm
  
    global String GetPresentedClid(String clickToDialResult){
          
        Map<String,Object> clickToDialResultMap = (Map<String,Object>)JSON.deserializeUntyped(clickToDialResult);
        String customerNumber = (String)clickToDialResultMap.get('number');
        
        //Account default
        String presentedClid = '01234567890';
          
        if (customerNumber.startsWith('07') || customerNumber.startsWith('+447')) {
            //Mobile, or cell, numbers
            presentedClid = '07123456789';
        } else if (customerNumber.startsWith('0207') || customerNumber.startsWith('+44207')) {
            //Basingstoke numbers
            presentedClid = '02071234567';
        }
          
        return presentedClid;    
    }
}