Page Comparison

When you have created your class, ensure that ContactWorld VCC uses the class in Salesforce. For information about configuring the class that ContactWorld VCC uses to select the presented CLID, see Configuring custom settings for optional Vonage Contact Center features in Salesforce.

You can create different Apex classes to define callback behaviors for different departments and users. Define the required class for specific profiles or users in hierachical custom settings.

In our first example, the presented callback number is stored in and retrieved from a custom field, called ClickToDialPresentedClid, on an Account object. Firstly we created an Account object field called ClickToDialPresentedClid. For information about creating custom fields, see Salesforce help.

Secondly, we created a new Apex class called SelectPresentedClidForContactByAccount:

global class SelectPresentedClidForContactByAccount implements NVMContactWorld.ISelectPresentedClid{
    
    // The clickToDialResult parameter contains the response string from the Salesforce ClickToDial event.
    // Salesforce passes the clickToDialResult parameter to us:
    // for example '{number: "07890123456", objectId: "0032000001FTGSo", object: "Contact"}'
    // Find more information at: https://www.salesforce.com/us/developer/docs/api_cti/Content/sforce_api_cti_onclicktodial.htm
 
    global String GetPresentedClid(String clickToDialResult){
         
        Map<String,Object> clickToDialResultMap = (Map<String,Object>)JSON.deserializeUntyped(clickToDialResult);
        String contactId = (String)clickToDialResultMap.get('objectId');
         
        Contact c = [SELECT Id, AccountId FROM Contact WHERE Id = :contactId];
        Account a = [SELECT Id, ClickToDialPresentedClid__c FROM Account WHERE Id = :c.AccountId];
         
        String presentedClid = a.ClickToDialPresentedClid__c;
         
        return presentedClid;       
    }
}

When an agent clicks to dial a number in a contact record, ContactWorld VCC runs our GetPresentedClid method in the SelectPresentedClidForContactByAccount class, which implements the ISelectPresentedClid interface. The GetPresentedClid method performs the following tasks:

• receives the details (clickToDialResult) of the Click to dial event
• uses the objectId from clickToDialResult to identify the contact record from which the agent initiated the call
• locates the record for the account to which the contact belongs
• returns the number from the custom field (ClickToDialPresentedClid__c) on the account record

ContactWorld VCC uses the returned number as the callback number. The number appears both in ContactPad and on handset of the person that the agent has clicked to dial.

In our second example, the presented callback number is set according to whether the customer's telephone number is a mobile—or cell—number, a number with a London area code, or other number.

The Apex class that implements NVMContactWorld.SelectPresentedClidByPolicy is called SelectPresentedClidForContactByAccount:

global class SelectPresentedClidByPolicy implements NVMContactWorld.ISelectPresentedClid{
     
    // The clickToDialResult parameter contains the response string from the Salesforce ClickToDial event.
    // Salesforce passes the clickToDialResult parameter to us:
    // for example '{number: "07890123456", objectId: "0032000001FTGSo", object: "Contact"}'
    // Find more information at: https://www.salesforce.com/us/developer/docs/api_cti/Content/sforce_api_cti_onclicktodial.htm
  
    global String GetPresentedClid(String clickToDialResult){
          
        Map<String,Object> clickToDialResultMap = (Map<String,Object>)JSON.deserializeUntyped(clickToDialResult);
        String customerNumber = (String)clickToDialResultMap.get('number');
        
        //Account default
        String presentedClid = '01234567890';
          
        if (customerNumber.startsWith('07') || customerNumber.startsWith('+447')) {
            //Mobile, or cell, numbers
            presentedClid = '07123456789';
        } else if (customerNumber.startsWith('0207') || customerNumber.startsWith('+44207')) {
            //Basingstoke numbers
            presentedClid = '02071234567';
        }
          
        return presentedClid;    
    }
}

When an agent clicks to dial a number in a contact record, ContactWorld VCC runs the GetPresentedClid method in the SelectPresentedClidByPolicy. The GetPresentedClid method performs the following tasks:

• receives the details (clickToDialResult) of the Click to dial event
• uses the number from clickToDialResult to identify the customer's telephone number, which the agent clicked to dial
• returns the appropriate number:
  • if the customer's number is a mobile number, the method returns a mobile number
  • if the customer's number has a London area code, the method returns a London area code
  • if the customer's number is any other number, the method returns the default number (01234567890)

ContactWorld VCC uses the returned number as the callback number. The number appears both in ContactPad and on handset of the person that the agent has clicked to dial.